function v = MisuraTensione(N1,N2,Rete,R)
    //
    // Determina la misura della tensione tra il nodo N1 ed il nodo N2 del
    // circuito descritto nella lista Rete rilevata con un voltmetro
    // schematizzato come un resistore di resistenza R.
    //
    // Si osservi che l'inserimento del voltmetro modifica il circuito
    // che deve quindi essere nuovamente descritto e simulato per determinare
    // la tensione richiesta.
    //
    // Rete: lista di due matrici che descrive il circuito nel quale
    //       si inserisce il voltmetro.
    // N1, N2: numero dei nodi del circuito descritto da Rete tra i quali
    //         si inserisce il voltmetro.
    // R: valore della resistenza del resistore con cui si schematizza il
    //    voltmetro. Se R = %inf si sta utilizzando per la misura un voltmetro
    //    ideale.
    // v: differenza tra la tensione del nodo N1 e quella del nodo N2 nel
    //    circuito contenente il voltmetro.
    //
    // Inserisce il resistore di resistenza R nel circuito descritto da Rete
    Voltmetro = [R,N1,N2];
    [RES,GEN] = Rete(:);
    RES = [RES;Voltmetro];
    ReteConVoltmetro = list(RES,GEN);
    // Determina i dati delle equazioni nodali
    [G, J] = EquazioniNodali(ReteConVoltmetro);
    // (1) fattorizzazione di G
    [S,D,P] = lu(G);
    // (2) soluzione del sistema S c = PJ
    c = SA(S, P*J);
    // (3) soluzione del sistema D x = c
    E = SI(D,c);
    // Determina il valore della tensione ai capi del resistore che
    // rappresenta il voltmetro.
    if (N1 ~= 0 & N2 ~= 0) then v = E(N1) - E(N2); end;
    if N1 == 0 then v = -E(N2); else v = E(N1); end;
endfunction
