// Inserire qui il percorso del file di nome bisezione.sce
Percorso='/home/ciampa/Lavoro/Scilab/Zeri/Metodi/';
exec(Percorso+'bisezione.sce');
//
function y = f_test_1(x)
    y = cos(x)
endfunction
//
function y = f_test_2(x)
    y = (x-2).^13
endfunction
//
function y = f_test_2_h(x)
    y = horner(poly(2*ones(1,13),'X'),x)
endfunction
//
a = 1.1;
b = 3.21; // con f_test_2_h, cambiare in b = 3.2 e vedere come cambia z...
tol = 1d-15;
kmax = 60;
//
[z,v,info] = bisezione(f_test_2_h,a,b,"assoluto",tol,kmax,"loquace")
//
printf("z = ");disp(z);
printf("v = ");disp(v);
printf("info = ");disp(info);
//
// grafici
//
scf(0); clf(0); // opera nella finestra grafica numero 0: se non esiste
                // la genera, altrimenti la vuota
//
// grafico superiore
//
subplot(211);
t = linspace(1.8,2.2,3000);
//
plot(t,f_test_2_h(t),"b");
plot(t,f_test_2(t),"g");
// impostazione dello spessore (thickness) dell'ultima curva disegnata
figura=gca();
figura.children.children(1).thickness=3
// griglia
xgrid();
// etichetta asse orizzontale
xlabel("t");
// legenda
legend("f_test_2_h (t)","f_test_2 (t)")
//
// grafico inferiore
//
subplot(212);
//
t = z + [-1000:1000]*2*%eps; // qualche numero di macchina prima e dopo z...
//
plot(f_test_2_h(t),"b");
plot(f_test_2(t),"g");
plot(1001,v,"ro");
//
figura=gca();
figura.children.children(2).thickness=3
xgrid();
xlabel("k   (valore di t corrispondente: z + 2 (k-1001) %eps )");
legend("f_test_2_h (t)","f_test_2 (t)","(z,f(z))")
